Making a USB Windows 7 System repair key

I’m replacing my DVD drive with a second harddrive bay and the only reason I currently need the DVD is in case I need to do a system repair, to start the windows repair utility.

Annoyingly the System repair utility doesn’t allow you to specify a USB drive as the destination for your repair disc.

To find out what I needed I created a system disc properly and then copied the files to the USB drive and heh presto it worked.

I didn’t want to waste DVD but couldn’t find any other way to find the files I needed.

The files you need can be found on the setup disk.

You need,

\boot\bcd
\boot\boot.sdi
\boot\bootfix.bin
\sources\boot.wim
\bootmgr

The files (and importantly the wim I think) are the full setup files and not just the repair ones, so you get the setup dialogue, thats fine it just means that you have to click the repair option when the setup dialogue fires.

I’ve created a useful batch file to copy the files you want.

@echo off
echo ---------------------------------------------------------
echo .
echo . Windows 7 System Repair disk creation.
echo .
echo . This allows you to copy the required files for a system
echo . repair disk to any device.
echo .
echo . Simon Sabin 2010 http://sqlblogcasts.com/blogs/simons
echo ---------------------------------------------------------
echo .

if "%1"=="" (
echo You need to specify a drive and optionally a folder to get the source files from
echo There should be a folder called boot and sources in that location
goto error
)
if "%2"=="" (
echo You need to specify a drive to use as the repair drive
goto error
)

set source=%1%
set target=%2%
set err=0

if exist "%target%\*.*" (
echo Files already exist on the target, if you continue they will be overwritten
choice /C YN /M "Do you want to continue?"
if errorlevel 2 ( goto exit)
)

if not exist "%source%\boot\bcd" (
echo The bcd file in the boot folder is missing
set err=1
)
if not exist "%source%\boot\bootfix.bin" (
echo The bootfix.bin file in the boot folder is missing
set err=1
)
if not exist "%source%\boot\boot.sdi" (
echo The boot.sdi file in the boot folder is missing
set err=1
)
if not exist "%source%\sources\boot.wim" (
echo The boot.wim file in the sources folder is missing
set err=1
)
if not exist "%source%\bootmgr" (
echo The bootmgr file in the root folder is missing
set err=1
)

if "%err%" == "1" (
goto error
)

if not exist %target%\boot mkdir %target%\boot
if not exist %target%\sources mkdir %target%\sources
xcopy %source%\boot\bcd %target%\boot /Y
xcopy %source%\boot\boot.sdi %target%\boot /Y
xcopy %source%\boot\bootfix.bin %target%\boot /Y
xcopy %source%\sources\boot.wim %target%\sources /Y
xcopy %source%\bootmgr %target% /Y

got :exit
:error
echo An error occurred
echo .
echo Example
echo . MakeSystem f: g:
echo .
echo . This copies the system repair files from the media on f: to the g: drive
echo .
echo This program copies the following files on to the target
echo \boot\bcd
echo \boot\boot.sdi
echo \boot\bootfix.bin
echo \sources\boot.wim
echo \bootmgr

:exit